Eğitimler


KeyboardMessage

Bu örnekte düğmeye basıldığında, bilgisayara klavye girişi olarak bir metin dizesi gönderilir. Dize, düğmeye kaç kez basıldığını bildirir. Leonardo programlandıktan ve bağlandıktan sonra, sonuçları görmek için favori metin düzenleyicinizi açın.

NB: Keyboard.print () komutunu kullandığınızda, Arduino bilgisayarınızın klavyesini devralır! Bu işlevle bir çizim çalıştırırken bilgisayarınızın kontrolünü kaybetmemenizi sağlamak için Keyboard.print () öğesini aramadan önce güvenilir bir kontrol sistemi kurduğunuzdan emin olun. Bu çizim, klavyeyi değiştirmek için bir düğmeye sahiptir, böylece yalnızca düğmeye basıldıktan sonra çalışır.

Gerekli Donanım

  • Arduino Leonardo, Micro veya Due board
  • anlık buton
  • 10k ohm direnç

Yazılım Gerekli

  • Herhangi bir metin düzenleyici

Devre

Butonun bir pimini Arduino'daki pime 4'e takın. Diğer pimi 5V'ye takın. Direnci, pim 4'ten toprağa takarak toprağa referans sağlayan bir aşağı çekme olarak kullanın.

Kartınızı programladıktan sonra, USB kablosunu çıkarın, bir metin düzenleyici açın ve metin imlecini yazma alanına yerleştirin. Kartı USB üzerinden tekrar bilgisayarınıza bağlayın ve belgeye yazmak için düğmesine basın.

Kod 


/*
  Keyboard Message test

  For the Arduino Leonardo and Micro.

  Sends a text string when a button is pressed.

  The circuit:
  - pushbutton attached from pin 4 to +5V
  - 10 kilohm resistor attached from pin 4 to ground

  created 24 Oct 2011
  modified 27 Mar 2012
  by Tom Igoe
  modified 11 Nov 2013
  by Scott Fitzgerald

  This example code is in the public domain.

  http://www.arduino.cc/en/Tutorial/KeyboardMessage
*/

#include "Keyboard.h"

const int buttonPin = 4;          // input pin for pushbutton
int previousButtonState = HIGH;   // for checking the state of a pushButton
int counter = 0;                  // button push counter

void setup() {
  // make the pushButton pin an input:
  pinMode(buttonPin, INPUT);
  // initialize control over the keyboard:
  Keyboard.begin();
}

void loop() {
  // read the pushbutton:
  int buttonState = digitalRead(buttonPin);
  // if the button state has changed,
  if ((buttonState != previousButtonState)
      // and it's currently pressed:
      && (buttonState == HIGH)) {
    // increment the button counter
    counter++;
    // type out a message
    Keyboard.print("You pressed the button ");
    Keyboard.print(counter);
    Keyboard.println(" times.");
  }
  // save the current button state for comparison next time:
  previousButtonState = buttonState;
}

See Also