Eğitimler


ChatServer

Gelen iletileri bağlı tüm istemcilere dağıtan basit bir sunucu. Kullanmak için bir terminal penceresi açın, cihazlarınızın IP adresine Telnet yazın ve yazın. Gelen metinler bağlı tüm istemcilere gönderilecektir (bir tanesi dahil). Ayrıca, müşterinin girişini seri monitörünüzde de görebilirsiniz.

Gerekli Donanım

Devre

Ethernet kalkanı, bir WizNet Ethernet denetleyicisini SPI veri yolu üzerinden Arduino veya Genuino kartlarına bağlamanızı sağlar. WizNet'e SPI bağlantısı için 10, 11, 12 ve 13 pinlerini kullanır . Ethernet kalkanının sonraki modellerinde de bir SD Kart bulunur. Dijital pim 4, SD karttaki ikincil seçim pimini kontrol etmek için kullanılır.

Kalkan bir ethernet kablosuyla bir ağa bağlanmalıdır. Programdaki ağ ayarlarını ağınıza uygun olacak şekilde değiştirmeniz gerekecektir.

Yukarıdaki görüntüde, Arduino veya Genuino kartı Ethernet kalkanının altına istiflenecektir.

Şematik

Kod:

Lütfen dikkat : donanım kurulumunuza göre, çizimin başındaki kütüphaneleri yorumlamanız / açmanız gerekir. Arduino Ethernet Shield 2 ve Leonardo Ethernet ile Arduino Ethernet Shield veya Ethernet2.h ile kullanın Ethernet.h.

/*
 Chat Server

 A simple server that distributes any incoming messages to all
 connected clients.  To use, telnet to your device's IP address and type.
 You can see the client's input in the serial monitor as well.
 Using an Arduino Wiznet Ethernet shield.

 Circuit:
 * Ethernet shield attached to pins 10, 11, 12, 13

 created 18 Dec 2009
 by David A. Mellis
 modified 9 Apr 2012
 by Tom Igoe

 */

#include <SPI.h>
#include <Ethernet.h>

// Enter a MAC address and IP address for your controller below.
// The IP address will be dependent on your local network.
// gateway and subnet are optional:
byte mac[] = {
  0xDE, 0xAD, 0xBE, 0xEF, 0xFE, 0xED };
IPAddress ip(192, 168, 1, 177);
IPAddress myDns(192, 168, 1, 1);
IPAddress gateway(192, 168, 1, 1);
IPAddress subnet(255, 255, 0, 0);


// telnet defaults to port 23
EthernetServer server(23);
bool alreadyConnected = false; // whether or not the client was connected previously

void setup() {
  // You can use Ethernet.init(pin) to configure the CS pin
  //Ethernet.init(10);  // Most Arduino shields
  //Ethernet.init(5);   // MKR ETH shield
  //Ethernet.init(0);   // Teensy 2.0
  //Ethernet.init(20);  // Teensy++ 2.0
  //Ethernet.init(15);  // ESP8266 with Adafruit Featherwing Ethernet
  //Ethernet.init(33);  // ESP32 with Adafruit Featherwing Ethernet

  // initialize the ethernet device
  Ethernet.begin(mac, ip, myDns, gateway, subnet);

  // Open serial communications and wait for port to open:
  Serial.begin(9600);
   while (!Serial) {
    ; // wait for serial port to connect. Needed for native USB port only
  }

  // Check for Ethernet hardware present
  if (Ethernet.hardwareStatus() == EthernetNoHardware) {
    Serial.println("Ethernet shield was not found.  Sorry, can't run without hardware. :(");
    while (true) {
      delay(1); // do nothing, no point running without Ethernet hardware
    }
  }
  if (Ethernet.linkStatus() == LinkOFF) {
    Serial.println("Ethernet cable is not connected.");
  }

  // start listening for clients
  server.begin();

  Serial.print("Chat server address:");
  Serial.println(Ethernet.localIP());
}

void loop() {
  // wait for a new client:
  EthernetClient client = server.available();

  // when the client sends the first byte, say hello:
  if (client) {
    if (!alreadyConnected) {
      // clear out the input buffer:
      client.flush();
      Serial.println("We have a new client");
      client.println("Hello, client!");
      alreadyConnected = true;
    }

    if (client.available() > 0) {
      // read the bytes incoming from the client:
      char thisChar = client.read();
      // echo the bytes back to the client:
      server.write(thisChar);
      // echo the bytes to the server as well:
      Serial.write(thisChar);
    }
  }
}
[Kodu Al]

See Also