Eğitimler


Wifi101WiFiWebServer

Bu örnekte, basit bir Web sunucusu oluşturmak için WiFi Shield 101'inizi ve Arduino veya Genuino Zero'nuzu veya bir MKR1000 kartınızı kullanacaksınız . WiFi kitaplığını kullanarak, cihazınız WiFI bağlantısından alınan bir HTTP isteğini yanıtlayabilecektir. Bir tarayıcı açıp WiFi kalkanınızın veya MKR1000'in IP adresine gittikten sonra , kartınız bir tarayıcının altı analog pimin tüm giriş değerlerini göstermesi için yeterli HTML ile yanıt verecektir.

Bu örnek, WPA şifrelemesi kullanan bir ağ için yazılmıştır. WEP veya WPA için Wifi.begin () çağrısını uygun şekilde değiştirin.

Gerekli Donanım

  • Arduino WiFi Kalkanı 101
  • Arduino veya Genuino Zero kartı

veya

  • MKR1000
  • (isteğe bağlı) analog girişlere takılacak bazı sensörler

Devre

Dijital pim 7, WiFi Shield 101 ile kart arasında el sıkışma pimi olarak kullanılır ve kullanılmamalıdır.

Bu örnek için İnternet'e bağlanan bir 802.11b / g kablosuz ağa erişiminizin olması gerekir. Çizimdeki ağ ayarlarını, belirli ağlarınızın SSID'sine karşılık gelecek şekilde değiştirmeniz gerekecektir.

WPA / WPA2 Kişisel şifreleme kullanan ağlar için SSID ve parolaya ihtiyacınız vardır. Kalkan WPA2 Enterprise şifrelemesi kullanan ağlara bağlanmaz.

WEP ağ parolaları, anahtarlar olarak bilinen onaltılık dizelerdir. WEP ağında 4 farklı anahtar bulunabilir; her tuşa bir "Anahtar Dizini" değeri atanır. WEP şifreli ağlar için SSID'ye, anahtara ve anahtar numarasına ihtiyacınız vardır.

Yukarıdaki görüntüde, Arduino veya Genuino Zero kartı WiFi kalkanının altında istiflenecekti.

Kod

/*
  WiFi Web Server

 A simple web server that shows the value of the analog input pins.
 using a WiFi shield.

 This example is written for a network using WPA encryption. For
 WEP or WPA, change the WiFi.begin() call accordingly.

 Circuit:
 * WiFi shield attached
 * Analog inputs attached to pins A0 through A5 (optional)

 created 13 July 2010
 by dlf (Metodo2 srl)
 modified 31 May 2012
 by Tom Igoe

 */

#include <SPI.h>
#include <WiFi101.h>


#include "arduino_secrets.h"
///////please enter your sensitive data in the Secret tab/arduino_secrets.h
char ssid[] = SECRET_SSID;        // your network SSID (name)
char pass[] = SECRET_PASS;    // your network password (use for WPA, or use as key for WEP)
int keyIndex = 0;                 // your network key Index number (needed only for WEP)

int status = WL_IDLE_STATUS;

WiFiServer server(80);

void setup() {
  //Initialize serial and wait for port to open:
  Serial.begin(9600);
  while (!Serial) {
    ; // wait for serial port to connect. Needed for native USB port only
  }

  // check for the presence of the shield:
  if (WiFi.status() == WL_NO_SHIELD) {
    Serial.println("WiFi shield not present");
    // don't continue:
    while (true);
  }

  // attempt to connect to WiFi network:
  while (status != WL_CONNECTED) {
    Serial.print("Attempting to connect to SSID: ");
    Serial.println(ssid);
    // Connect to WPA/WPA2 network. Change this line if using open or WEP network:
    status = WiFi.begin(ssid, pass);

    // wait 10 seconds for connection:
    delay(10000);
  }
  server.begin();
  // you're connected now, so print out the status:
  printWiFiStatus();
}


void loop() {
  // listen for incoming clients
  WiFiClient client = server.available();
  if (client) {
    Serial.println("new client");
    // an http request ends with a blank line
    bool currentLineIsBlank = true;
    while (client.connected()) {
      if (client.available()) {
        char c = client.read();
        Serial.write(c);
        // if you've gotten to the end of the line (received a newline
        // character) and the line is blank, the http request has ended,
        // so you can send a reply
        if (c == '\n' && currentLineIsBlank) {
          // send a standard http response header
          client.println("HTTP/1.1 200 OK");
          client.println("Content-Type: text/html");
          client.println("Connection: close");  // the connection will be closed after completion of the response
          client.println("Refresh: 5");  // refresh the page automatically every 5 sec
          client.println();
          client.println("<!DOCTYPE HTML>");
          client.println("<html>");
          // output the value of each analog input pin
          for (int analogChannel = 0; analogChannel < 6; analogChannel++) {
            int sensorReading = analogRead(analogChannel);
            client.print("analog input ");
            client.print(analogChannel);
            client.print(" is ");
            client.print(sensorReading);
            client.println("<br />");
          }
          client.println("</html>");
          break;
        }
        if (c == '\n') {
          // you're starting a new line
          currentLineIsBlank = true;
        }
        else if (c != '\r') {
          // you've gotten a character on the current line
          currentLineIsBlank = false;
        }
      }
    }
    // give the web browser time to receive the data
    delay(1);

    // close the connection:
    client.stop();
    Serial.println("client disconnected");
  }
}


void printWiFiStatus() {
  // print the SSID of the network you're attached to:
  Serial.print("SSID: ");
  Serial.println(WiFi.SSID());

  // print your WiFi shield's IP address:
  IPAddress ip = WiFi.localIP();
  Serial.print("IP Address: ");
  Serial.println(ip);

  // print the received signal strength:
  long rssi = WiFi.RSSI();
  Serial.print("signal strength (RSSI):");
  Serial.print(rssi);
  Serial.println(" dBm");
}
[Kodu Al]

See Also

  • WiFi library- WiFi101 Kütüphanesi için referansınız.
  • WiFi Shield- WiFi 101 Shield ürün detayları.
  • MKR1000- MKR1000 kartı için ürün detayları.