Eğitimler


Wifi101ConnectWithWEP

Bu örnek, Arduino WiFi kalkanı 101 veya MKR1000 kartıyla WEP şifreli 802.11b / g ağına nasıl bağlanacağınızı gösterir. Arduino Software (IDE) seri monitörünüz bağlandıktan sonra bağlantı hakkında bilgi verecektir.

Gerekli Donanım

  • Arduino WiFi Kalkanı 101
  • Arduino veya Genuino Zero kartı

veya

  • MKR1000

Devre

Dijital pim 7, WiFi Shield 101 ile kart arasında el sıkışma pimi olarak kullanılır ve kullanılmamalıdır.

Bu örnek için İnternet'e bağlanan bir 802.11b / g kablosuz ağa erişiminizin olması gerekir. Çizimdeki ağ ayarlarını, belirli ağlarınızın SSID'sine karşılık gelecek şekilde değiştirmeniz gerekecektir.

WEP ağ parolaları, anahtarlar olarak bilinen onaltılık dizelerdir. WEP ağında 4 farklı anahtar bulunabilir; her tuşa bir "Anahtar Dizini" değeri atanır. WEP şifreli ağlar için SSID'ye, anahtara ve anahtar numarasına ihtiyacınız vardır.

Yukarıdaki görüntüde, Arduino veya Genuino Zero kartı WiFi kalkanının altında istiflenecekti.

Kod

/*

 This example connects to a WEP-encrypted WiFi network.
 Then it prints the  MAC address of the WiFi shield,
 the IP address obtained, and other network details.

 If you use 40-bit WEP, you need a key that is 10 characters long,
 and the characters must be hexadecimal (0-9 or A-F).
 e.g.  for 40-bit, ABBADEAF01 will work, but ABBADEAF won't work
 (too short) and ABBAISDEAF won't work (I and S are not
 hexadecimal characters).

 For 128-bit, you need a string that is 26 characters long.
 D0D0DEADF00DABBADEAFBEADED will work because it's 26 characters,
 all in the 0-9, A-F range.

 Circuit:
 * WiFi shield attached

 created 13 July 2010
 by dlf (Metodo2 srl)
 modified 31 May 2012
 by Tom Igoe
 */
#include <SPI.h>
#include <WiFi101.h>

#include "arduino_secrets.h"
///////please enter your sensitive data in the Secret tab/arduino_secrets.h
char ssid[] = SECRET_SSID;        // your network SSID (name)
char key[] = SECRET_PASS;    // your network password (use for WPA, or use as key for WEP)
int keyIndex = 0;                                // your network key Index number
int status = WL_IDLE_STATUS;                     // the WiFi radio's status

void setup() {
  //Initialize serial and wait for port to open:
  Serial.begin(9600);
  while (!Serial) {
    ; // wait for serial port to connect. Needed for native USB port only
  }

  // check for the presence of the shield:
  if (WiFi.status() == WL_NO_SHIELD) {
    Serial.println("WiFi shield not present");
    // don't continue:
    while (true);
  }

  // attempt to connect to WiFi network:
  while ( status != WL_CONNECTED) {
    Serial.print("Attempting to connect to WEP network, SSID: ");
    Serial.println(ssid);
    status = WiFi.begin(ssid, keyIndex, key);

    // wait 10 seconds for connection:
    delay(10000);
  }

  // once you are connected :
  Serial.print("You're connected to the network");
  printCurrentNet();
  printWiFiData();
}

void loop() {
  // check the network connection once every 10 seconds:
  delay(10000);
  printCurrentNet();
}

void printWiFiData() {
  // print your WiFi shield's IP address:
  IPAddress ip = WiFi.localIP();
  Serial.print("IP Address: ");
  Serial.println(ip);
  Serial.println(ip);

  // print your MAC address:
  byte mac[6];
  WiFi.macAddress(mac);
  Serial.print("MAC address: ");
  printMacAddress(mac);
}

void printCurrentNet() {
  // print the SSID of the network you're attached to:
  Serial.print("SSID: ");
  Serial.println(WiFi.SSID());

  // print the MAC address of the router you're attached to:
  byte bssid[6];
  WiFi.BSSID(bssid);
  Serial.print("BSSID: ");
  printMacAddress(bssid);

  // print the received signal strength:
  long rssi = WiFi.RSSI();
  Serial.print("signal strength (RSSI):");
  Serial.println(rssi);

  // print the encryption type:
  byte encryption = WiFi.encryptionType();
  Serial.print("Encryption Type:");
  Serial.println(encryption, HEX);
  Serial.println();
}

void printMacAddress(byte mac[]) {
  for (int i = 5; i >= 0; i--) {
    if (mac[i] < 16) {
      Serial.print("0");
    }
    Serial.print(mac[i], HEX);
    if (i > 0) {
      Serial.print(":");
    }
  }
  Serial.println();
}
[Kodu Al]

See Also

  • WiFi library- WiFi101 Kütüphanesi için referansınız.
  • WiFi Shield- WiFi 101 Shield ürün detayları.
  • MKR1000- MKR1000 kartı için ürün detayları.