Eğitimler


DumpFile

Bu örnek, SD kitaplığını kullanarak bir SD karttan bir dosyanın nasıl okunacağını ve seri port üzerinden nasıl gönderileceğini gösterir. SD kütüphanesi hakkında daha fazla bilgi için lütfen buraya tıklayın .

Gerekli Donanım

  • Arduino veya Genuino kartı
  • Ethernet Kalkanı (veya SD yuvalı başka bir kart)
  • Bazı metinler içeren "datalog.txt" adlı bir dosyaya sahip biçimlendirilmiş SD kart

Devre

Arduino veya Genuino kartı Ethernet Kalkanına bağlı olmalı ve ayrıca bilgisayara bağlı bir USB kablosu olmalıdır.

Şemalar

Kod

Aşağıdaki kod, yerleşik SD yuvasına sahip bir Ethernet kalkanı ile kullanım için yapılandırılmıştır. In setup() , çağrı SD.begin() CS pin olarak pimi 4 adlandırma. Bu pim, kullandığınız kalkanın veya kartın markasına bağlı olarak değişir.

SD kartta "datalog.txt" adlı bir dosya var. loop() SD.open() dosya açılır. Dosyayı seri olarak bir bilgisayara göndermek için, Serial.print() ile dosyanın içeriğini okuyarak SD.read() .

/*
  SD card file dump

  This example shows how to read a file from the SD card using the
  SD library and send it over the serial port.

  The circuit:
   SD card attached to SPI bus as follows:
 ** MOSI - pin 11
 ** MISO - pin 12
 ** CLK - pin 13
 ** CS - pin 4 (for MKRZero SD: SDCARD_SS_PIN)

  created  22 December 2010
  by Limor Fried
  modified 9 Apr 2012
  by Tom Igoe

  This example code is in the public domain.

*/

#include <SPI.h>
#include <SD.h>

const int chipSelect = 4;

void setup() {
  // Open serial communications and wait for port to open:
  Serial.begin(9600);
  while (!Serial) {
    ; // wait for serial port to connect. Needed for native USB port only
  }


  Serial.print("Initializing SD card...");

  // see if the card is present and can be initialized:
  if (!SD.begin(chipSelect)) {
    Serial.println("Card failed, or not present");
    // don't do anything more:
    while (1);
  }
  Serial.println("card initialized.");

  // open the file. note that only one file can be open at a time,
  // so you have to close this one before opening another.
  File dataFile = SD.open("datalog.txt");

  // if the file is available, write to it:
  if (dataFile) {
    while (dataFile.available()) {
      Serial.write(dataFile.read());
    }
    dataFile.close();
  }
  // if the file isn't open, pop up an error:
  else {
    Serial.println("error opening datalog.txt");
  }
}

void loop() {
}
[Kodu Al]

See Also


  • CardInfo- SD kartınız hakkında bilgi alın.
  • Datalogger- Üç analog sensörden bir SD karta veri nasıl kaydedilir.
  • Files- Nasıl bir SD kart dosyası oluşturmak ve yok etmek.
  • Listfiles- SD karttaki bir dizindeki dosyaların yazdırılması.
  • ReadWrite- Bir SD karta ve SD karttan veri okuma ve yazma.