Eğitimler


CardInfo

Bu örnek bir SD kart hakkındaki bilgilerin nasıl okunacağını gösterir. Örnekte, birim kitaplığını, boş alanı ve SD kitaplığını kullanarak diğer bilgileri seri bağlantı noktası üzerinden gönderir. SD kütüphanesi hakkında daha fazla bilgi için lütfen buraya tıklayın .

Gerekli Donanım

  • Arduino veya Genuino kartı
  • Ethernet Kalkanı (veya SD yuvalı başka bir kart)
  • Biçimlendirilmiş SD kart

Devre

Arduino veya Genuino kartı Ethernet Kalkanına bağlı olmalı ve ayrıca bilgisayara bağlı bir USB kablosu olmalıdır.

Şemalar

Kod

Aşağıdaki kod, yerleşik SD yuvasına sahip bir Ethernet kalkanı ile kullanım için yapılandırılmıştır. In setup() , çağrı SD.begin() CS pin olarak pimi 4 adlandırma. Bu pim, kullandığınız kalkanın veya kartın markasına bağlı olarak değişir.

Kod, SD kartla ilgili bilgileri bildirmek için belgelenmemiş bazı yardımcı program kitaplıkları kullanır. Bu bilgiler, biçimlendirme ( FAT16 veya FAT32 ) ve dosya yapısının yanı sıra kartta kullanılan boş alan ve alan miktarını içerir.

/*
  SD card test

  This example shows how use the utility libraries on which the'
  SD library is based in order to get info about your SD card.
  Very useful for testing a card when you're not sure whether its working or not.

  The circuit:
    SD card attached to SPI bus as follows:
 ** MOSI - pin 11 on Arduino Uno/Duemilanove/Diecimila
 ** MISO - pin 12 on Arduino Uno/Duemilanove/Diecimila
 ** CLK - pin 13 on Arduino Uno/Duemilanove/Diecimila
 ** CS - depends on your SD card shield or module.
        Pin 4 used here for consistency with other Arduino examples


  created  28 Mar 2011
  by Limor Fried
  modified 9 Apr 2012
  by Tom Igoe
*/
// include the SD library:
#include <SPI.h>
#include <SD.h>

// set up variables using the SD utility library functions:
Sd2Card card;
SdVolume volume;
SdFile root;

// change this to match your SD shield or module;
// Arduino Ethernet shield: pin 4
// Adafruit SD shields and modules: pin 10
// Sparkfun SD shield: pin 8
// MKRZero SD: SDCARD_SS_PIN
const int chipSelect = 4;

void setup() {
  // Open serial communications and wait for port to open:
  Serial.begin(9600);
  while (!Serial) {
    ; // wait for serial port to connect. Needed for native USB port only
  }


  Serial.print("\nInitializing SD card...");

  // we'll use the initialization code from the utility libraries
  // since we're just testing if the card is working!
  if (!card.init(SPI_HALF_SPEED, chipSelect)) {
    Serial.println("initialization failed. Things to check:");
    Serial.println("* is a card inserted?");
    Serial.println("* is your wiring correct?");
    Serial.println("* did you change the chipSelect pin to match your shield or module?");
    while (1);
  } else {
    Serial.println("Wiring is correct and a card is present.");
  }

  // print the type of card
  Serial.println();
  Serial.print("Card type:         ");
  switch (card.type()) {
    case SD_CARD_TYPE_SD1:
      Serial.println("SD1");
      break;
    case SD_CARD_TYPE_SD2:
      Serial.println("SD2");
      break;
    case SD_CARD_TYPE_SDHC:
      Serial.println("SDHC");
      break;
    default:
      Serial.println("Unknown");
  }

  // Now we will try to open the 'volume'/'partition' - it should be FAT16 or FAT32
  if (!volume.init(card)) {
    Serial.println("Could not find FAT16/FAT32 partition.\nMake sure you've formatted the card");
    while (1);
  }

  Serial.print("Clusters:          ");
  Serial.println(volume.clusterCount());
  Serial.print("Blocks x Cluster:  ");
  Serial.println(volume.blocksPerCluster());

  Serial.print("Total Blocks:      ");
  Serial.println(volume.blocksPerCluster() * volume.clusterCount());
  Serial.println();

  // print the type and size of the first FAT-type volume
  uint32_t volumesize;
  Serial.print("Volume type is:    FAT");
  Serial.println(volume.fatType(), DEC);

  volumesize = volume.blocksPerCluster();    // clusters are collections of blocks
  volumesize *= volume.clusterCount();       // we'll have a lot of clusters
  volumesize /= 2;                           // SD card blocks are always 512 bytes (2 blocks are 1KB)
  Serial.print("Volume size (Kb):  ");
  Serial.println(volumesize);
  Serial.print("Volume size (Mb):  ");
  volumesize /= 1024;
  Serial.println(volumesize);
  Serial.print("Volume size (Gb):  ");
  Serial.println((float)volumesize / 1024.0);

  Serial.println("\nFiles found on the card (name, date and size in bytes): ");
  root.openRoot(volume);

  // list all files in the card with date and size
  root.ls(LS_R | LS_DATE | LS_SIZE);
  root.close();
}

void loop(void) {
}
[Kodu Al]

Lütfen dikkat: küme boyutu kullanıcı tarafından format zamanında tanımlanır ve bazı kurallara göre kullanıcılar tarafından değiştirilebilen bazı varsayılan değerlere sahiptir. Yukarıdaki çizimde, standartlara göre 512 bayta ayarlanmış bir blok için varsayılan boyutu kullanıyoruz. Bu değer küme boyutu değil: küme başına blok sayısı olarak hesaplanır. Bu makalede küme boyutları hakkında daha ayrıntılı bilgi bulabilirsiniz.

See Also


  • Datalogger- Üç analog sensörden bir SD karta veri nasıl kaydedilir.
  • DumpFile- SD karttan bir dosya nasıl okunur.
  • Files- Nasıl bir SD kart dosyası oluşturmak ve yok etmek.
  • Listfiles- SD karttaki bir dizindeki dosyaların yazdırılması.
  • ReadWrite- Bir SD karta ve SD karttan veri okuma ve yazma.