Eğitimler


Datalogger

Bu örnek, üç analog sensörden bir SD karta veri kaydetmek için SD kart Kitaplığının nasıl kullanılacağını gösterir. SD kütüphanesi hakkında daha fazla bilgi için lütfen buraya tıklayın .

Gerekli Donanım

  • Arduino veya Genuino kartı
  • Ethernet Kalkanı (veya SD yuvalı başka bir kart)
  • 3 10k ohm potansiyometre
  • bağlantı telleri
  • breadboard
  • Biçimlendirilmiş SD kart

Devre

Arduino veya Genuino kartı Ethernet Kalkanına bağlı olmalıdır. Üç potansiyometre, arabirim tekniklerine göre bağlanacak olan diğer analog sensörlerle değiştirilebilir.

Şemalar

Kod

Aşağıdaki kod, yerleşik SD yuvasına sahip bir Ethernet kalkanı ile kullanım için yapılandırılmıştır. In setup() , çağrı SD.begin() CS pin olarak pimi 4 adlandırma. Bu pim, kalkanın veya kartın markasına bağlı olarak değişir.

loop() , üç analog sensörden gelen bilgileri tutmak için bir String oluşturulur. Kod, sensörleri yineleyerek verilerini dizeye ekler.

Ardından, SD karttaki dosya SD.open() çağrılarak SD.open() . Kullanılabilir olduğunda, dataFile.println() kullanıldığında veriler karta yazılır. Bilgileri kaydetmek için dosya dataFile.close() ile kapatılmalıdır.

/*
  SD card datalogger

  This example shows how to log data from three analog sensors
  to an SD card using the SD library.

  The circuit:
   analog sensors on analog ins 0, 1, and 2
   SD card attached to SPI bus as follows:
 ** MOSI - pin 11
 ** MISO - pin 12
 ** CLK - pin 13
 ** CS - pin 4 (for MKRZero SD: SDCARD_SS_PIN)

  created  24 Nov 2010
  modified 9 Apr 2012
  by Tom Igoe

  This example code is in the public domain.

*/

#include <SPI.h>
#include <SD.h>

const int chipSelect = 4;

void setup() {
  // Open serial communications and wait for port to open:
  Serial.begin(9600);
  while (!Serial) {
    ; // wait for serial port to connect. Needed for native USB port only
  }


  Serial.print("Initializing SD card...");

  // see if the card is present and can be initialized:
  if (!SD.begin(chipSelect)) {
    Serial.println("Card failed, or not present");
    // don't do anything more:
    while (1);
  }
  Serial.println("card initialized.");
}

void loop() {
  // make a string for assembling the data to log:
  String dataString = "";

  // read three sensors and append to the string:
  for (int analogPin = 0; analogPin < 3; analogPin++) {
    int sensor = analogRead(analogPin);
    dataString += String(sensor);
    if (analogPin < 2) {
      dataString += ",";
    }
  }

  // open the file. note that only one file can be open at a time,
  // so you have to close this one before opening another.
  File dataFile = SD.open("datalog.txt", FILE_WRITE);

  // if the file is available, write to it:
  if (dataFile) {
    dataFile.println(dataString);
    dataFile.close();
    // print to the serial port too:
    Serial.println(dataString);
  }
  // if the file isn't open, pop up an error:
  else {
    Serial.println("error opening datalog.txt");
  }
}
[Kodu Al]

See Also


  • CardInfo- SD kartınız hakkında bilgi alın.
  • DumpFile- SD karttan bir dosya nasıl okunur.
  • Files- Nasıl bir SD kart dosyası oluşturmak ve yok etmek.
  • Listfiles- SD karttaki bir dizindeki dosyaların yazdırılması.
  • ReadWrite- Bir SD karta ve SD karttan veri okuma ve yazma.