Eğitimler


TwoPortReceive

Arduino ve Genuino kartları, 0 ve 1 pinlerinde seri iletişim için dahili destek sunar, ancak daha fazla seri bağlantı noktasına ihtiyacınız varsa? SoftwareSerial Library , kablolu RX ve TX hatlarının işlevselliğini çoğaltmak için yazılım kullanarak, seri iletişimin panolarınızın diğer dijital pinlerinde gerçekleşmesini sağlamak için geliştirilmiştir. Bu, iki seri özellikli cihazla iletişim kurma veya ana seri portu hata ayıklama amacıyla açık bırakırken sadece bir cihazla konuşma ihtiyacı ortaya çıktığında son derece yararlı olabilir.

Aşağıdaki örnekte, Arduino veya Genuino kartınızdaki dijital pin 2 ve 4 sanal RX seri hatları olarak kullanılmıştır. Pim 3 ve 5 sanal TX çizgileridir. Kart bir "?" Alana kadar bir sanal bağlantı noktasını (portOne) dinler. karakter. Bundan sonra, ikinci sanal bağlantı noktasını (portTwo) dinler.

Gerekli Donanım

  • Arduino veya Genuino Kurulu

Devre

Bu örnek için devre yok. Arduino Yazılımının (IDE) seri monitör penceresinden seri iletişimi sağlamak için Arduino veya Genuino kartınızın USB üzerinden bilgisayarınıza bağlı olduğundan emin olun.

Şemalar

Kod


/*
  Software serial multple serial test

 Receives from the two software serial ports,
 sends to the hardware serial port.

 In order to listen on a software port, you call port.listen().
 When using two software serial ports, you have to switch ports
 by listen()ing on each one in turn. Pick a logical time to switch
 ports, like the end of an expected transmission, or when the
 buffer is empty. This example switches ports when there is nothing
 more to read from a port

 The circuit:
 Two devices which communicate serially are needed.
 * First serial device's TX attached to digital pin 10(RX), RX to pin 11(TX)
 * Second serial device's TX attached to digital pin 8(RX), RX to pin 9(TX)

 Note:
 Not all pins on the Mega and Mega 2560 support change interrupts,
 so only the following can be used for RX:
 10, 11, 12, 13, 50, 51, 52, 53, 62, 63, 64, 65, 66, 67, 68, 69

 Not all pins on the Leonardo support change interrupts,
 so only the following can be used for RX:
 8, 9, 10, 11, 14 (MISO), 15 (SCK), 16 (MOSI).

 created 18 Apr. 2011
 modified 19 March 2016
 by Tom Igoe
 based on Mikal Hart's twoPortRXExample

 This example code is in the public domain.

 */

#include <SoftwareSerial.h>
// software serial #1: RX = digital pin 10, TX = digital pin 11
SoftwareSerial portOne(10, 11);

// software serial #2: RX = digital pin 8, TX = digital pin 9
// on the Mega, use other pins instead, since 8 and 9 don't work on the Mega
SoftwareSerial portTwo(8, 9);

void setup() {
  // Open serial communications and wait for port to open:
  Serial.begin(9600);
  while (!Serial) {
    ; // wait for serial port to connect. Needed for native USB port only
  }


  // Start each software serial port
  portOne.begin(9600);
  portTwo.begin(9600);
}

void loop() {
  // By default, the last intialized port is listening.
  // when you want to listen on a port, explicitly select it:
  portOne.listen();
  Serial.println("Data from port one:");
  // while there is data coming in, read it
  // and send to the hardware serial port:
  while (portOne.available() > 0) {
    char inByte = portOne.read();
    Serial.write(inByte);
  }

  // blank line to separate data from the two ports:
  Serial.println();

  // Now listen on the second port
  portTwo.listen();
  // while there is data coming in, read it
  // and send to the hardware serial port:
  Serial.println("Data from port two:");
  while (portTwo.available() > 0) {
    char inByte = portTwo.read();
    Serial.write(inByte);
  }

  // blank line to separate data from the two ports:
  Serial.println();
}
 
[Kodu Al]

See Also