connectSSL()

Açıklama

SSL protokolünü kullanarak yapıcıda belirtilen IP adresine ve bağlantı noktasına bağlanın. Sunucu yalnızca HTTPS bağlantıları sağladığında connectSSL yöntemi gereklidir. Bu yöntemi kullanmadan önce, sunucu tarafından kullanılan SSL sertifikasının Arduino WiFi modülüne yüklenmesi gerekir. Kartlar önceden sertifikalarla birlikte gelir ve kullanıma hazır olmalıdır. Yeni SSL sertifikalarını değiştirmek veya yüklemek için kullanılabilir hale getirilecek prosedürleri izlemelisiniz. connectSSL (), bir alan adı kullanırken DNS aramalarını da destekler (ör: google.com).

Sözdizimi

client.connectSSL (ip, bağlantı noktası)
client.connectSSL (URL, bağlantı noktası)

Parametreler

ip: istemcinin bağlanacağı IP adresi (4 baytlık dizi)

URL: istemcinin bağlanacağı alan adı (dize, ör .:"arduino.cc ")

port: istemcinin bağlanacağı port (int)

İadeler

Bağlantı başarılı olursa true değerini, değilse false değerini döndürür.

Misal

…

/*
Web client

This sketch connects to a website through a SSL connection
using a WiFi board.

This example is written for a network using WPA encryption. For
WEP or WPA, change the Wifi.begin() call accordingly.

Circuit:
* WiFiNINA supported board

created 13 July 2010
by dlf (Metodo2 srl)
modified 31 May 2012
by Tom Igoe
*/

#include <SPI.h>
#include <WiFiNINA.h>

char ssid[] = "yourNetwork"; // your network SSID (name)
char pass[] = "secretPassword"; // your network password (use for WPA, or use as key for WEP)
int keyIndex = 0; // your network key Index number (needed only for WEP)

int status = WL_IDLE_STATUS;
char server[] = "www.arduino.cc"; // name address for Arduino (using DNS)

// Initialize the Wifi client library
// with the IP address and port of the server
// that you want to connect to (port 80 is default for HTTP):
WiFiClient client;

void setup() {
//Initialize serial and wait for port to open:
Serial.begin(9600);
while (!Serial) {
; // wait for serial port to connect. Needed for Leonardo only
}

// attempt to connect to Wifi network:
while (status != WL_CONNECTED) {
Serial.print("Attempting to connect to SSID: ");
Serial.println(ssid);
// Connect to WPA/WPA2 network. Change this line if using open or WEP network:
status = WiFi.begin(ssid, pass);

// wait 10 seconds for connection:
delay(10000);
}
Serial.println("Connected to wifi");

Serial.println("\nStarting connection to server...");
// if you get a connection, report back via serial:
if (client.connectSSL(server, 443)) {
Serial.println("Connected to server");
// Make a HTTP request:
client.println("GET /asciilogo.txt HTTP/1.1");
client.println("Host: www.arduino.cc");
client.println("Connection: close");
client.println();
Serial.println("Request sent");
}
}

void loop() {
// if there are incoming bytes available
// from the server, read them and print them:
while (client.available()) {
char c = client.read();
Serial.write(c);
}

// if the server's disconnected, stop the client:
if (!client.connected()) {
Serial.println();
Serial.println("disconnecting from server.");
client.stop();

// do nothing forevermore:
while (true);
}
}

…

Komut